Како користити Цапс Лоцк као модификаторски тастер на Виндовс-у

Taster Caps Lock, koji se nalazi na istaknutom mestu tastature, često ne opravdava svoju poziciju. Ovaj jednostavan AutoHotkey skripta transformisaće Caps Lock u taster za modifikaciju, omogućavajući vam da ga koristite za kreiranje sopstvenih prečica.

Osnove

Ovaj skript vam omogućava da, na primer, pritiskom na kombinaciju tastera Caps Lock + G, brzo pretražite tekst na Google-u sa bilo koje lokacije u Windows-u. Ili, pritiskom na Caps Lock + D, možete potražiti definiciju reči u rečniku. Naravno, ove prečice se mogu prilagoditi vašim potrebama.

Najbolja stvar je to što ovaj pametni skript i dalje vam omogućava da normalno koristite Caps Lock. Možete ga uključiti i isključiti brzim dvostrukim pritiskom. Ako to ne učinite, Caps Lock će služiti kao taster za modifikaciju za prečice.

AutoHotkey 101

AutoHotkey je besplatna Windows aplikacija koja radi u pozadini i izvršava skripte. Možete sami pisati ove skripte ili ih preuzeti sa interneta. Skripte uglavnom reaguju na pritisak tastera i izvršavaju određene radnje. AutoHotkey je brz način za premapiranje tastera u Windows-u ili dodeljivanje različitih funkcija određenim tasterima.

Na primer, pokazali smo kako možete koristiti AutoHotkey da onemogućite Windows taster, sprečavajući da otvara Start meni i da vas izbacuje iz igara preko celog ekrana. Ne morate otvarati kućište računara i dirati tastaturu.

Instalacija AutoHotkey-a i preuzimanje skripte

Preuzmite AutoHotkey i instalirajte ga da biste počeli. Zatim, preuzmite CapsLock Modifier skriptu.

Raspakujte AHK skriptu iz ZIP arhive i smestite je u bilo koju fasciklu na vašem računaru. Da biste je pokrenuli pomoću AutoHotkey-a, kliknite desnim tasterom miša na skriptu i odaberite „Run script“.

Skripta je sada aktivna u pozadini. Da biste uključili ili isključili Caps Lock, brzo dvaput dodirnite taster Caps Lock.

Ako ne dodirnete dvaput, Caps Lock će delovati isključivo kao taster za modifikaciju. Sa funkcijama ugrađenim u skriptu, možete koristiti sledeće prečice bilo gde u Windows-u:

Pritisnite Caps Lock + D da biste pronašli definiciju izabrane reči.
Pritisnite Caps Lock + G da biste pretražili izabrani tekst na Google-u.
Pritisnite Caps Lock + T da biste potražili izabranu reč u tezaurusu.
Pritisnite Caps Lock + V da biste pretražili izabrani tekst na Wikipediji.

Želite više prečica? Možete kreirati sopstvene uz malo znanja o AutoHotkey skriptama.

Da biste kontrolisali AutoHotkey, potražite ikonu AutoHotkey u području obaveštenja – ima zelenu pozadinu sa belim H na njoj. Da biste zaustavili izvršavanje skripte, kliknite desnim tasterom miša na ikonu AutoHotkey i odaberite „Exit“.

Kako to funkcioniše?

Ako želite da vidite kako skripta funkcioniše, kliknite desnim tasterom miša na nju i odaberite „Edit script“. Ovo će otvoriti skriptu u Notepad-u i možete pregledati njen kod. Skripta je prilično kratka i laka za razumevanje. Preporučujemo da ne preuzimate i ne pokrećete nepoznate skripte pre nego što ih pregledate i razumete.

Ovu skriptu nam je poslao Dejv Kelog. Evo ključnog dela skripte koji omogućava da Caps Lock funkcioniše kao taster za modifikaciju osim ako se ne pritisne dvaput:

CapsLock::
KeyWait, CapsLock ; Čeka da se Capslock otpusti.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 ako CapsLock nije pritisnut u roku od 0.2 sekunde.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Da li je dvostruki pritisak na CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Menja stanje CapsLock LED
}
return

Ovaj deo čeka da vidi da li je Caps Lock pritisnut dva puta i, ako jeste, uključuje ili isključuje Caps Lock. U suprotnom, skripta hvata Caps Lock i koristi ga za modifikacione prečice.

Ostatak skripte sadrži prečice i korisnu funkciju međuspremnika koja čuva sadržaj vašeg međuspremnika i vraća ga. Taj deo je prilično neophodan, pošto funkcije modifikatora koriste međuspremnik da izvrše radnje na izabranom tekstu.

Želite da vidite celu skriptu bez preuzimanja? Izvolite:

#NoEnv                      ; Preporučuje se za performanse i kompatibilnost sa budućim izdanjima AutoHotkey-a.
; #Warn                     ; Omogućava upozorenja da bi pomogla u otkrivanju uobičajenih grešaka.
#SingleInstance FORCE       ; Preskače dijalog za pozivanje i tiho zamenjuje prethodno pokrenutu instancu ovog skripta.
SendMode Input              ; Preporučuje se za nove skripte zbog svoje superiorne brzine i pouzdanosti.
SetWorkingDir %A_ScriptDir%  ; Osigurava dosledan početni direktorijum.


;================================================================================================
;  Obrada CapsLock-a. Morate dvaput dodirnuti CapsLock da biste uključili ili isključili režim CapsLock-a.
;================================================================================================
; Morate dvaput dodirnuti CapsLock da biste uključili ili isključili režim CapsLock-a.
CapsLock::
    KeyWait, CapsLock                                                   ; Čeka da se Capslock otpusti.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 ako CapsLock nije pritisnut u roku od 0.2 sekunde.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Da li je dvostruki pritisak na CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Menja stanje CapsLock LED
        }
return



;================================================================================================
; Prečice sa CapsLock modifikatorom. Pogledajte https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Dobij DEFINICIJU izabrane reči.
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Pokreće sa sadržajem međuspremnika
    ClipboardRestore()
Return

; GOOGLE izabrani tekst.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Pokreće sa sadržajem međuspremnika
    ClipboardRestore()
Return

; Pronalazi TEZAURUS izabrane reči
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Pokreće sa sadržajem međuspremnika
    ClipboardRestore()
Return

; Otvara WIKIPEDIJU za izabranu reč
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Pokreće sa sadržajem međuspremnika
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Pomoćne funkcije za međuspremnik.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Čuva postojeći međuspremnik.
    Clipboard:= ""
    Send, ^c                                            ;Kopira izabrani tekst u međuspremnik
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, Nije izabran tekst!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Već smo videli AutoHotkey skripte koje pretvaraju Caps Lock u taster za modifikaciju, ali nikada onu koja drži Caps Lock kao prekidač ako ga dvaput pritisnete. Vrlo je pametno. Još jednom, hvala Dejvu Kelogu što nam je poslao.