Како користити Цапс Лоцк као модификаторски тастер на Виндовс-у

Цапс Лоцк тастер заузима прво место на тастатури и не повлачи своју тежину. Ова једноставна АутоХоткеи скрипта ће претворити Цапс Лоцк у модификаторски тастер тако да га можете користити за прилагодљиве пречице.

Основе

Ова скрипта ће вам омогућити да притиснете Цапс Лоцк+Г да брзо Гоогле текст са било ког места у Виндовс-у или притиснете Цапс Лоцк+Д да бисте потражили дефиницију речи у речнику. Ове пречице су, наравно, прилагодљиве.

Најбоље од свега, ова паметна скрипта вам и даље омогућава да нормално користите Цапс Лоцк. Цапс Лоцк можете укључити и искључити брзим притиском двапут. Ако то не учините, Цапс Лоцк ће функционисати као модификатор за пречице.

АутоХоткеи 101

АутоХоткеи је бесплатна Виндовс апликација која се налази у позадини и покреће скрипте. Можете сами написати ове скрипте или их преузети. Скрипте углавном чекају на притисак на тастер и извршавају радњу. На овај начин, АутоХоткеи је брз начин за поновно мапирање тастера у Виндовс-у или додељивање различитих радњи тастерима.

На пример, показали смо како можете да користите АутоХоткеи да онемогућите тастер Виндовс, спречавајући га да отвори мени Старт и избаци вас из игрица преко целог екрана на рачунару. Нема потребе да скидате поклопац са тастатуре.

Инсталирајте АутоХоткеи и преузмите скрипту

Преузмите АутоХоткеи и инсталирајте га за почетак. Затим преузмите скрипту ЦапсЛоцк Модифиер.

Извуците датотеку АХК скрипте из ЗИП архивске датотеке и ставите је у било коју фасциклу на рачунару. Да бисте га покренули помоћу АутоХоткеи-а, кликните десним тастером миша на скрипту и изаберите „Покрени скрипту“.

Скрипта сада ради у позадини. Да бисте укључили и искључили Цапс Лоцк, брзо двапут додирните тастер Цапс Лоцк.

Ако не додирнете двапут, Цапс Лоцк функционише само као модификаторски тастер. Са функцијама уграђеним у скрипту, можете да користите следеће пречице било где у Виндовс-у:

Притисните Цапс Лоцк + д да бисте пронашли речничку дефиницију изабране речи.
Притисните Цапс Лоцк + г да бисте тражили на Гоогле-у изабрани текст било где у Виндовс-у.
Притисните Цапс Лоцк + т да бисте пронашли изабрану реч у тезаурусу.
Притисните Цапс Лоцк + в да бисте тражили изабрани текст на Википедији.

Желите више пречица? Можете креирати своје са мало знања о АутоХоткеи скриптама.

Да бисте контролисали АутоХоткеи, потражите икону АутоХоткеи у пољу за обавештавање—она има зелену позадину са белим Х на њој. Да бисте зауставили покретање скрипте, само кликните десним тастером миша на икону АутоХоткеи и изаберите „Изађи“.

Како то функционише?

Ако желите да видите шта ради скрипта, кликните десним тастером миша на њу и уместо тога изаберите „Уреди скрипту“. Ово ће отворити скрипту у Нотепад-у и можете да прегледате њен код. Сценарио је прилично кратак и лако разумљив. Препоручујемо да не преузимате и не покрећете чудне скрипте без да их прво погледате и разумете.

Овај сценарио нам је послао Даве Келлог. Ево магичног дела скрипте који чини да Цапс Лоцк функционише као тастер за модификацију ако се притисне двапут:

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

Овај бит чека да види да ли се Цапс Лоцк притисне двапут и укључује или искључи Цапс Лоцк. У супротном, скрипта хвата Цапс Лоцк и користи га за пречице за модификацију.

Остатак скрипте садржи пречице и корисну функцију међуспремника која чува садржај вашег међуспремника и враћа га. Тај део је прилично неопходан, пошто функције модификатора користе међуспремник за предузимање радњи на изабраном тексту.

Желите да видите целу скрипту без преузимања? Ево га:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Већ смо видели АутоХоткеи скрипте које претварају Цапс Лоцк у тастер за модификацију, али никада ону која држи Цапс Лоцк као прекидач ако га двапут притиснете. Веома је паметно. Још једном хвала Даве Келлогу што нам га је послао.